Loading URL encoded variables into a Flash application using the URLLoader class in ActionScript 3.0

The following example shows how you can load an external text files with URL encoded variables using ActionScript 2.0 and ActionScript 3.0.

Full code after the jump.

The following example shows how you can load an external text file with URL encoded variables into an ActionScript 2.0 document using the LoadVars class:

// ActionScript 2.0
var loadVars:LoadVars = new LoadVars();
loadVars.onLoad = function(success:Boolean):Void {
    if (success) {
        lbl.text = loadVars.lastName + "," + loadVars.firstName; // Jones,Tom
    } else {
        lbl.text = "unable to load text file.";
    }
}
loadVars.load("params.txt");

Note that this time ActionScript 2.0 is using the onLoad event handler instead of the onData event handler. The difference? Well, onData gets called before the loaded text is parsed, whereas onLoad gets called after onData and after the text has been parsed into variables.

You may recall from the previous entry, “Loading text files using the URLLoader class in ActionScript 3.0″, that the onData event handler receives a single String parameter, which is the raw unparsed text. The onLoad event handler receives a single Boolean parameter, which reports whether the text was able to be parsed successfully or not.

The following example shows how you can load an external text file with URL encoded variables into an ActionScript 3.0 document using the URLLoader class and setting the dataFormat property to the URLLoaderDataFormat.VARIABLES constant (“variables”):

// ActionScript 3.0
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
}

And what, exactly, does this “params.txt” text file look like?

firstName=Tom&lastName=Jones

Tagged as: dataFormat, LoadVars, onLoad(), URLLoader, URLLoaderDataFormat